home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
BBS Toolkit
/
BBS Toolkit.iso
/
qbbs
/
multisb.zip
/
N2.BAT
< prev
Wrap
DOS Batch File
|
1992-02-16
|
5KB
|
212 lines
@ECHO OFF
REM Read Node 1 batch to get some info on this one, the two are basically the
REM same except this one does no mail processing.
if exist i:\fd\fd2.up goto FD_UP
Echo Clearing environemental variables...
set SHEZEX=
set SHEZWORK=
set LIST=
Echo Setting new variables...
set FD=C:\FD\FD2
set DSZLOG=I:\SBBS\DSZLOG.N2
set DSZPORT=2
set SUPER=Y
set TCNODE=2
set LOCK=9600
set BAUD=0
ansi
dc frame off /q
:FRT_DOOR
echo
set BAUD=0
if not exist i:\fd\fd2.up rem > i:\fd\fd2.up
if exist e:\uploads\downloa2.* del e:\uploads\downloa2.* > nul
if exist i:\sbbs\n2.up del i:\sbbs\n2.up > nul
if exist c:\sbbs\n2\xrs\*.pkt goto XRSMAIL
%FOS%
c:
cd\sbbs
sbbsutil nodestatus 2 2
cd\fd\fd2
cls
fd
if errorlevel 255 goto FRT_DOOR
if exist c:\sbbs\n2\doorcfg.bbs del c:\sbbs\n2\doorcfg.bbs > nul
rem > i:\sbbs\n2.up
if errorlevel 214 goto 14400_baud
if errorlevel 196 goto 9600_baud
if errorlevel 148 goto 4800_baud
if errorlevel 124 goto 2400_baud
if errorlevel 112 goto 1200_baud
if errorlevel 103 goto 300_baud
if errorlevel 100 goto LOCAL
del i:\sbbs\n2.up > nul
if errorlevel 96 goto WAIT_FOR_OK
if errorlevel 95 goto NET_ECHO
if errorlevel 94 goto ECHO_ONLY
if errorlevel 93 goto NET_ONLY
if errorlevel 90 goto UNPACK_MAIL
if errorlevel 55 goto WEEKLY
if errorlevel 50 goto COMMO
if errorlevel 45 goto MIDNIGHT
if errorlevel 40 goto NIGHTLY
if errorlevel 10 goto QUIT
if errorlevel 5 goto MODEM_INIT
goto FRT_DOOR
:14400_baud
set BAUD=14400
cd\sbbs\n2
bbs -n2 -* -o100000 -b14400 -e0
goto BBS_ERRLVL
:9600_baud
set BAUD=9600
cd\sbbs\n2
bbs -n2 -* -o100000 -b9600 -e0
goto BBS_ERRLVL
:4800_baud
set BAUD=4800
cd\sbbs\n2
bbs -n2 -* -o100000 -b4800 -e0
goto BBS_ERRLVL
:2400_baud
set BAUD=2400
cd\sbbs\n2
bbs -n2 -* -o100000 -b2400 -e0
goto BBS_ERRLVL
:1200_baud
set BAUD=1200
cd\sbbs\n2
bbs -n2 -* -o100000 -b1200 -e0
goto BBS_ERRLVL
:300_baud
set BAUD=300
cd\sbbs\n2
bbs -n2 -* -o100000 -b300 -e0
goto BBS_ERRLVL
:LOCAL
set BAUD=0
cd\sbbs\n2
bbs -n2 -* -o100000 -l -e0
goto BBS_ERRLVL
:RELOAD
cd\sbbs\n2
bbs -n2 -* -o100000 -b%BAUD% -e0
goto BBS_ERRLVL
:RET_BBS
if exist c:\sbbs\n2\doorcfg.bbs del c:\sbbs\n2\doorcfg.bbs > nul
c:
cd\sbbs\n2
bbs -n2 -* -o100000 -R -e0
:BBS_ERRLVL
if errorlevel 80 goto RELOAD
if errorlevel 70 goto RET_BBS
if errorlevel 60 goto DOSDOOR
if errorlevel 50 goto LIST
if exist i:\sbbs\n2.up del i:\sbbs\n2.up
if errorlevel 5 goto NET_ECHO
if errorlevel 4 goto ECHO_ONLY
if errorlevel 3 goto NET_ONLY
if errorlevel 2 goto QUIT
:LOOPBACK
if %BAUD%==0 goto FRT_DOOR
dc beep 200,1 0,2 /r=2 /q
if exist sbbsswap.$$$ del sbbsswap.$$$ > nul
if exist i:\sbbs\n?.up goto FRT_DOOR
cd\sbbs
last 5 c:\sbbs\scallers.bbs
goto FRT_DOOR
:DOSDOOR
cd\sbbs\n2
QKDOOR QBBS GAP
DOORWAY.EXE SYS /i:c:\ext\doorpass /f /o:t /v:d^U /K:0 /C:DOS
goto RET_BBS
:LIST
cd\sbbs\n2
QKDOOR QBBS GAP
DOORWAY.EXE SYS /i:c:\ext\doorpass /f /o:t /v:d^U /p:c:\xtg\ld.com
goto RET_BBS
:COMMO
cd\commo
if not exist gedown.now goto FRT_DOOR
del i:\fd\fd2.up > nul
commo GEnie_Auto_Down
rem > i:\fd\fd2.up
goto FRT_DOOR
:MIDNIGHT
rem > c:\fd\fd1\fdexit.45
goto WAIT_FOR_OK
:NIGHTLY
rem > c:\fd\fd1\fdexit.40
goto WAIT_FOR_OK
:WEEKLY
rem > c:\fd\fd1\fdexit.55
goto WAIT_FOR_OK
:WAIT_FOR_OK
rem > i:\sbbs\fdevent.ok
wait! t i:\sbbs\fdevent.ovr
del i:\sbbs\fdevent.ovr > nul
goto FRT_DOOR
:NET_ECHO
:ECHO_ONLY
rem > c:\fd\fd1\fdexit.95
goto LOOPBACK
:NET_ONLY
rem > c:\fd\fd1\fdexit.93
goto LOOPBACK
:XRSMAIL
copy c:\sbbs\n2\xrs\*.pkt c:\fd\inbound > nul
del c:\sbbs\n2\xrs\*.pkt > nul
:UNPACK_MAIL
rem > c:\fd\fd1\fdexit.90
goto FRT_DOOR
:MODEM_INIT
echo ~~~+++~~~ATH~~~ > COM1
be ask "Press A to abort FD startup! C to Continue." ca default=c timeout=9
if errorlevel 2 goto QUIT
goto FRT_DOOR
:FD_UP
cls
echo Node 2 of Frontdoor is allready running, check the windows...
echo Press ALT, then S to switch and see which windows are open.
echo If things don't look right and no one is on line 1 press ALT
echo then FX to run Fix Frontdoor nodes...
pause
exit
:QUIT
if exist i:\sbbs\n2.up del i:\sbbs\n2.up > nul
if exist i:\fd\fd2.up del i:\fd\fd2.up > nul
sbbsutil nodestatus 2 1
echo ATZ > COM2
exit